Merge remote-tracking branch 'origin/cuup-load-tester' into integration_2025_w32 (!3547)

Add a CU-UP load tester and improve GTP performance This adds a simple tester program for the CU-UP. It sets up a number of UEs/bearers in the CU-UP via the E1 interface, then streams data in downlink/uplink (as seen by the CU-UP). More information is available in tests/nr-cuup/README.md. Includes some fixes to properly verify that SCTP is installed, and use "the right cmake way" to use it in cmake code (see commit for details).
2025-08-04 23:59:05 +02:00
parent de91ab6eb9 6bf88bd3d9
commit d630fb2965
37 changed files with 1431 additions and 1016 deletions
@@ -1,46 +0,0 @@
-# - Try to find SCTP library and headers
-# Once done, this will define
-#
-#  SCTP_FOUND - system has SCTP
-#  SCTP_INCLUDE_DIR - the SCTP include directories
-#  SCTP_LIBRARIES - link these to use SCTP
-
-if (SCTP_INCLUDE_DIR AND SCTP_LIBRARIES)
-  set(SCTP_FIND_QUIETLY TRUE)
-endif (SCTP_INCLUDE_DIR AND SCTP_LIBRARIES)
-
-# Include dir
-find_path(SCTP_INCLUDE_DIR
-  NAMES netinet/sctp.h
-)
-
-# Library
-find_library(SCTP_LIBRARY
-  NAMES sctp
-)
-
-# Set the include dir variables and the libraries and let libfind_process do the rest.
-# NOTE: Singular variables for this library, plural for libraries this this lib depends on.
-#set(SCTP_PROCESS_INCLUDES SCTP_INCLUDE_DIR)
-#set(SCTP_PROCESS_LIBS SCTP_LIBRARY)
-#libfind_process(SCTP)
-
-
-# handle the QUIETLY and REQUIRED arguments and set SCTP_FOUND to TRUE if
-# all listed variables are TRUE
-INCLUDE(FindPackageHandleStandardArgs)
-FIND_PACKAGE_HANDLE_STANDARD_ARGS(SCTP DEFAULT_MSG SCTP_LIBRARY SCTP_INCLUDE_DIR)
-
-# If we successfully found the sctp library then add the library to the
-# SCTP_LIBRARIES cmake variable otherwise set SCTP_LIBRARIES to nothing.
-IF(SCTP_FOUND)
-   SET( SCTP_LIBRARIES ${SCTP_LIBRARY} )
-ELSE(SCTP_FOUND)
-   SET( SCTP_LIBRARIES )
-ENDIF(SCTP_FOUND)
-
-
-# Lastly make it so that the SCTP_LIBRARY and SCTP_INCLUDE_DIR variables
-# only show up under the advanced options in the gui cmake applications.
-MARK_AS_ADVANCED( SCTP_LIBRARY SCTP_INCLUDE_DIR )
-
@@ -0,0 +1,64 @@
+# - Try to find SCTP library and headers
+#
+# Imported Targets
+# ^^^^^^^^^^^^^^^^
+#
+# This module provides the following imported targets, if found:
+#
+# ``sctp::sctp``
+#   The SCTP library
+#
+# Result Variables
+# ^^^^^^^^^^^^^^^^
+#
+# this will define
+#
+#  sctp_FOUND - system has SCTP
+#  sctp_INCLUDE_DIRS - the SCTP include directories
+#  sctp_LIBRARIES - link these to use SCTP
+
+# Include dir
+find_path(sctp_INCLUDE_DIR
+  NAMES netinet/sctp.h
+)
+
+# Library
+find_library(sctp_LIBRARY
+  NAMES sctp
+)
+
+# Set the include dir variables and the libraries and let libfind_process do the rest.
+# NOTE: Singular variables for this library, plural for libraries this this lib depends on.
+#set(sctp_PROCESS_INCLUDES sctp_INCLUDE_DIR)
+#set(sctp_PROCESS_LIBS sctp_LIBRARY)
+#libfind_process(sctp)
+
+
+# handle the QUIETLY and REQUIRED arguments and set sctp_FOUND to TRUE if
+# all listed variables are TRUE
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(sctp
+  FOUND_VAR sctp_FOUND
+  REQUIRED_VARS
+    sctp_LIBRARY
+    sctp_INCLUDE_DIR
+)
+
+# If we successfully found the sctp library then add the library to the
+# sctp_LIBRARIES cmake variable otherwise set sctp_LIBRARIES to nothing.
+if(sctp_FOUND)
+   set(sctp_LIBRARIES ${sctp_LIBRARY})
+   set(sctp_INCLUDE_DIRS ${sctp_INCLUDE_DIR})
+endif()
+
+if(sctp_FOUND AND NOT TARGET sctp::sctp)
+  add_library(sctp::sctp UNKNOWN IMPORTED)
+  set_target_properties(sctp::sctp PROPERTIES
+    IMPORTED_LOCATION "${sctp_LIBRARY}"
+    INTERFACE_INCLUDE_DIRECTORIES "${sctp_INCLUDE_DIRS}"
+  )
+endif()
+
+# Lastly make it so that the SCTP_LIBRARY and SCTP_INCLUDE_DIR variables
+# only show up under the advanced options in the gui cmake applications.
+mark_as_advanced(SCTP_LIBRARY SCTP_INCLUDE_DIR)